Анализ операций с ценными бумагами с Microsoft Excel

В дополнение к уже рассмотренным, эти функции требуют задания следующих аргументов:

дата_вып – дата выпуска обязательства;

доход – требуемая норма доходности (рыночная ставка) Y;

ставка – годовая процентная ставка по сертификату r.

Продемонстрируем механизм работы этих функций на решении следующего примера . При этом для упрощения вычислений будем использовать обыкновенные проценты (360 / 360).

Пример 3.6

Коммерческий банк предлагает для юридических лиц депозитные сертификаты на предъявителя с номиналом от 1 до 100 млн. руб. Срок хранения сертификата от 1 до 6 месяцев. Доход по шестимесячному сертификату выпущенному 20/05/97 с номиналом в 1 млн. руб. установлен в размере 40% годовых. Произвести анализ этого предложения на дату 20/05/97.

Фрагмент ЭТ с решением данного примера приведен на рис. 3.9. Используемые в ЭТ формулы приведены в табл. 3.7.

  

Рис. 3.9. ЭТ для решения примера 3.6

Таблица 3.7  
Формулы ЭТ для анализа сертификатов

Ячейка	Формула
В10	=НАКОПДОХОДПОГАШ(B4;B5;B6;В7;E7)
В11	=B7+B10
В12	=НАКОПДОХОДПОГАШ(B4;E4;B6;В7;E7)
В15	=ЕСЛИ(B4=E4;B6;ДОХОДПОГАШ(E4;B5;B4;B6;E5;E7))
Е15	=ЕСЛИ(B4=E4;100;ЦЕНАПОГАШ(E4;B5;B4;B6;E6;E7))
В16	=E5+B12
В17	=B11-B16
В18	=ЕСЛИ(B4=E4;E5-B7;B10-B17)

Подготовьте исходную ЭТ, руководствуясь рис. 3.9 и табл. 3.7. Ниже приведены необходимые пояснения и рассмотрены используемые функции.

Функция НАКОПДОХОДПОГАШ(дата_вып; дата_вступл_в_силу; ставка; номинал; [базис])

Функция НАКОПДОХОДПОГАШ() вычисляет величину абсолютного дохода S по сертификату на момент погашения и является основной в данной группе. При этом аргумент "номинал" может быть задан как в виде абсолютной величины (например, 1000000), так и в процентах – 100. Здесь и в дальнейшем мы будем соблюдать правила фондового рынка и указывать подобные величины в процентах (т.е. курсовую стоимость 100 ед. обязательства). Заданная в ячейке В10, функция будет иметь следующий вид:

=НАКОПДОХОДПОГАШ(B4; B5; B6; В7; E7) (Результат: 20).

Таким образом, в конце срока операции на каждые 100 ед. номинала сертификата будет получен доход в 20 ед. Нетрудно определить, что в рассматриваемом примере накопленный доход при погашении сертификата в абсолютном измерении составит 200000 руб.

Этой же функцией можно воспользоваться для определения накопленного дохода продавца (в данном случае – банка) на дату проведения операции, т.е. величины S1. Формула для ее расчета задана в ячейке В12:

=НАКОПДОХОДПОГАШ(B4;Е4;B6;В7;E7) (Результат: 0).

Обратите внимание на то, что в этой формуле в качестве аргумента "дата_вступл_в_силу" используется ячейка Е4, содержащая дату продажи сертификата продавцом (приобретения покупателем). Поскольку дата продажи ценной бумаги совпадает с датой выпуска, величина накопленного к этому моменту времени дохода равна 0, что и отражает полученный результат. В данном случае вычисление величины S1 не имеет смысла, однако эта возможность пригодится нам в дальнейшем, при анализе операций купли-продажи.

Функция ДОХОДПОГАШ(дата_согл; дата_вступл_в_силу; дата_вып; ставка; цена; [базис])

Как следует из названия функции, она вычисляет доходность сертификата к погашению Y. Проблема использования функции заключается в том, что реализованный в ней алгоритм не допускает равенства аргументов "дата_согл" и "дата_вып" и выдает в подобных случаях ошибку.

С точки зрения теории, в условиях развитого финансового рынка проведение анализа этой ситуации действительно лишено смысла, как с точки эмитента (обязательство не может быть выпущено со ставкой доходности r ниже, чем рыночная ставка Y), так и с точки зрения инвестора (никто не купит ценную бумагу с доходностью ниже рыночной). Кроме того, все параметры операции в данном случае точно определены в контракте, либо приведены на бланке ценной бумаги.

Однако в целях повышения наглядности и обеспечения большей универсальности применения, в разрабатываемом шаблоне для анализа сертификатов и других аналогичных бумаг целесообразно предусмотреть возможность проведения вычислений и для такой ситуации.

В качестве одного из решений данной проблемы может быть предложено использование логической функции ЕСЛИ() при задании формулы вычисления доходности. Согласно предложенному подходу, формула, заданная в ячейке В15, будет иметь следующий вид:

=ЕСЛИ(B4=E4;B6;ДОХОДПОГАШ(E4;B5;B4;B6;E5;E7))

(Результат: 40%).

Таким образом, если сертификат приобретен в момент выпуска (т.е. даты в ячейках В4 и Е4 одинаковы), его доходность к погашению на дату сделки будет равна оговоренной в контракте (ячейка В6). В противном случае доходность Y будет вычисляться функцией ДОХОДПОГАШ().

Как и следовало ожидать, в рассматриваемом примере доходность к погашению равна объявленной, т.е. Y = r, поскольку сертификат был приобретен в момент выпуска.

Отметим, что по мере приближения даты покупки к сроку погашения, получение доходности, равной объявленной, возможно только в случае приобретения сертификата с соответствующим дисконтом.

Функция ЦЕНАПОГАШ(дата_согл; дата_вступл_в_силу; дата_вып; ставка; доход; [базис])

Функция ЦЕНАПОГАШ() возвращает курсовую стоимость обязательства, соответствующую требуемой норме доходности инвестора (рыночной ставке) Y, задаваемой аргументом "доход". Таким образом, она реализует соотношение (3.27) и вычисляет курс обязательства К, а не его полную стоимость Р. Забегая вперед отметим, что для определения полной рыночной стоимости обязательства Р, нам понадобится величина S1 (см. соотношения (3.26 – 3.29).

Как и функция ДОХОДПОГАШ(), она не допускает равенства аргументов "дата_согл" и "дата_вып". Таким образом для корректного решения задачи в данном случае мы вновь воспользуемся логической функцией ЕСЛИ() при задании формулы определения курсовой цены 100 ед. обязательства. Формула, заданная в ячейке Е18, будет иметь следующий вид:

=ЕСЛИ(B4=E4;100;ЦЕНАПОГАШ(E4;B5;B4;B6;E6;E7))

(Результат: 100).

Поскольку величина накопленного дохода на момент выпуска равна 0 (т.е. S1 = 0), курсовая стоимость К должна быть равна номиналу (т.е. К = N), что и отражает полученный результат.

Обратите внимание на то, что рассчитываемая в ячейке Е18 величина соответствует курсовой стоимости К, обеспечивающей получение требуемой нормы доходности (ячейка Е6). Таким образом она может отличаться от курсовой цены сделки (ячейка Е5).

Последние три строки ЭТ содержат формулы для расчета: полной стоимости сертификата (рыночной цены Р = К + S1) – ячейка В16; абсолютного дохода покупателя Sпок – ячейка В17; абсолютного дохода продавца – ячейка В18 (см. табл. 3.7). Как и следовало ожидать, в рассматриваемом примере эти величины соответствуют условиям контракта.

Формула в ячейке В18 имеет следующий вид:

=ЕСЛИ(B4=E4;B7-E5;B10-B17) (Результат: 0).

Заданная с использованием логической функции ЕСЛИ(), эта формула реализует два случая:

• если сертификат приобретается в момент выпуска (В4=Е4), доход определяется как разность между номиналом (ячейка В7) и ценой сделки (курсовой стоимостью – ячейка Е5);
• в других ситуациях формула реализует соотношение (3.25).

В рассматриваемом примере, поскольку сертификат приобретался в момент выпуска по номиналу, абсолютный доход продавца (банка) равен 0.

Отметим, что текущая доходность покупателя в этой операции на дату покупки сертификата равна: 20 / 100 = 0,2 или 20% (см. соотношение (3.23)).

Завершите формирование данной ЭТ. Очистив ячейки В4.В6 и Е4.Е6, получаем шаблон для анализа краткосрочных бумаг с выплатой процентного дохода в момент погашения (рис. 3.10).

Рис. 3.10. Шаблон для анализа краткосрочных сертификатов

Сохраните сформированный шаблон на магнитном диске под именем SH_CERT.XLT. Проверим работоспособность шаблона на решении более сложного примера.

Пример 3.7

Предположим, что владелец сертификата из предыдущего примера решил продать его через 4 месяца, т.е. 20.09.97. Котировочный курс владельца – 100. Провести анализ операции для покупателя на указанную дату, при условии, что рыночная ставка на этот момент по аналогичным обязательствам равна 45%.

Введите исходные данные примера в шаблон. Полученная в результате таблица должна иметь вид рис. 3.11.

Рис. 3.11. Предварительное решение примера 3.7

Как и следовало ожидать, операция явно невыгодна покупателю. Доходность сертификата к погашению, соответствующая рыночной ставке Y = 45%, почти на 10% ниже (ячейка В15). Причиной этому является завышенный курс обязательства (ячейка Е5), выставленный продавцом. Полная стоимость обязательства с учетом накопленного дохода при этом равна 113,33. Нетрудно заметить, что она соответствует норме доходности продавца, равной ставке по сертификату r = 40% и обеспечивает ему получение суммы в 13,33 (т.е. величины накопленного дохода по сертификату на момент совершения сделки – ячейка В12). Таким образом, распределение абсолютного дохода S (ячейка В10) при курсовой цене в 100,00 будет осуществляться в пользу продавца (ячейка В18).

Продолжим анализ. Курсовая стоимость, соответствующая норме доходности покупателя, рассчитана в ячейке Е15 и равна 98,29.

Введите в ячейку Е5: 98,29 или =Е15 .

Полученная в результате ЭТ приведена на рис. 3.12 и отражает ситуацию, соответствующую позиции покупателя (рынка).

Рис. 3.12. Итоговая ЭТ (пример 3.7)

Поскольку ставка по сертификату r на момент продажи ниже рыночной (т.е. требуемая покупателем норма доходности Y = 45%), курсовая цена за 100 ед. должна быть ниже номинала, что и отражает ее значение на дату предполагаемой сделки (98,29).

Величина накопленного к этому времени дохода (т.е. за 4 месяца) составила 13,33. Таким образом, полная стоимость сертификата Р, которую в данных условиях будет согласен уплатить покупатель, равна: 98,29 + 13,33 = 111,63 (ячейка В16). Погасив сертификат, покупатель получит доход: 120 - 111,63 = 8,37, или приблизительно 7,5% за 2 месяца (8,37 / 111,63 = 0,0749).

Абсолютный доход продавца будет равен: 111,63 - 100 = 11,63 на каждые 100 ед. номинала, или 11,63% за 4 месяца. Отметим, что неблагоприятное изменение процентной ставки (с 40% до 45%) на рынке снизило его абсолютный доход с 13,33 (ячейка В12) до 11,63 и соответственно – доходность к погашению, которая будет меньше объявленных по сертификату 40% годовых (расчеты показывают, что она равна 34,88%). Последнюю легко определить, воспользовавшись функцией ИНОРМА().

Функция ИНОРМА(дата_согл; дата_вступл_в_силу; инвестиция; погашение; [базис])

Функция вычисляет доходность финансовой операции, сущность проведения которой заключается в инвестировании некоторой суммы PV (аргумент "инвестиция") на дату начала операции (аргумент "дата_согл") и последующего получения суммы FV (аргумент "погашение") по завершению операции (аргумент "дата_вступл_в_силу"). Доходность операции возвращается в виде годовой ставки, рассчитанной по простым процентам.

При этом аргументы "инвестиция" и "погашение" могут задаваться как в виде абсолютных величин, так и в процентах (к 100 ед. номинала обязательства). Однако главное отличие этой функции заключается в том, что аргумент "погашение", независимо от способа задания, должен обязательно включать величину полученного или ожидаемого дохода: FV = S + N.

Как и большинство из рассматриваемых, функция ИНОРМА() не допускает равенства аргументов "дата_согл" и "дата_вступл_в_силу".

Для вычисления доходности продавца в нашем примере функция может быть задана следующим образом:

=ИНОРМА(B4; E4;100;111,63; E7) (Результат: 34,88%).

Обратите внимание на то, что в качестве аргумента "погашение" используется полная рыночная цена обязательства Р, а не сумма погашения (ячейка В11). Вы можете внести эту формулу в шаблон (например, в ячейку В19). Однако определяя доходность продавца следует всегда иметь в виду то обстоятельство, что аргумент "инвестиция" должен быть равен полной цене приобретения P1 на момент времени t = 1, а аргумент "погашение" – полной цене продажи P2 на момент времени t = 2. Если в нашем примере новый владелец сертификата решит продать его до срока погашения, например по цене 115,20, формула для определения доходности операции будет иметь следующий вид:

=ИНОРМА(дата_покупки; дата_продажи; 111,63; 115,20; E7).

Для задания аргументов "дата_покупки" и "дата_продажи" необходимо ввести соответствующие даты в любые свободные ячейки ЭТ, либо воспользоваться функциями преобразования дат (см. приложение 4).

В целом, функция ИНОРМА() обеспечивает большую универсальность применения и гибкость вычислений.

Полученное решение примера (рис. 3.12) соответствует ситуации рыночного равновесия в данных условиях. Любое отклонение цены сертификата в большую сторону будет в пользу продавца, безубыточная цена сделки для которого равна 100 + 13,33 = 113,33; в меньшую – принесет дополнительную прибыль покупателю.

В качестве упражнения, попробуйте поэксперементировать с исходными параметрами сделки. Проанализируйте полученные результаты.

Рассмотренные методы и спроектированный шаблон могут быть использованы для анализа любых краткосрочных обязательств, с выплатой фиксированного дохода в момент погашения, в т.ч. – векселей, выпущенных на подобных условиях.

3.4 Анализ операций с векселями

Вексель относится к наиболее сложной категории ценных бумаг. Это обусловлено многообразием тех функций, которые он может выполнять в процессе обращения. Существуют различные определения векселя, более или менее точно отражающие его сущность [5, 10, 11, 16].

В настоящей работе под векселем понимается ценная бумага, составленная по установленной законом форме и содержащая безусловное обязательство уплатить указанную в нем сумму в оговоренные сроки.